4 Special points in triangles

Oliver Knill, MathE - 320, Harvard Extension School, Spring 2010-2014

Just evaluate this notebook and you have a proof of the four miracle theorems: the existence of the centroid, orthocenter or centers for the inscribed or circumscribed circle. The code is a bit compressed. It is a good exercise to untangle it. For example: realize that L[x,y,z,w] gives the intersection point of two lines passing through x,y    and z,w.  Also an exercise is to see that f[{a,b,c}] gives a projection of the point c onto the line a,b.  This is used for the construction of the base points n,m,p in the orthocenter. Have fun. You will see that Ruelle has a point in that you do not gain much insight by running the code alone and just checking that the theorem is true. But if you understand the code, you can see an actual proof. It is Desquartes idea of turning geometry into algebra. You also see that the proof is not just an existence proof. It is constructive. You can actually give the coordinates of the point in question in each case. In the centroid case for example, the x coordinate of the point is the average of the x coordinates of the points. The proof also verifies that the intersection point cuts the lines in a 2:1 ratio.

Centroid

a={a1,a2};b={b1,b2};c={c1,c2};u=(b+c)/2;v=(a+c)/2;w=(a+b)/2;
p=(a+b+c)/3;Simplify[p==a/3+2u/3==b/3+2v/3==c/3+2w/3]

Orthocenter

a={a1,a2};b={b1,b2};c={c1,c2};
f[{a_,b_,c_}]:=a+(b-a)*((c-a).(b-a))/((b-a).(b-a));
m=f[{b,c,a}];n=f[{c,a,b}];p=f[{a,b,c}];
L[x_,y_,z_,w_]:=x+(t/.Solve[x+t (y-x)==z+s (w-z),{t,s}][[1]])(y-x);
Simplify[L[a,m,b,n]==L[a,m,c,p]==L[b,n,c,p]]

Cirumscribed Circle Center

Clear[a,b,c,u1,v1,v2,p,u2,v2,w2,L]

a={a1,a2};b={b1,b2};c={c1,c2};u1=(b+c)/2;v1=(a+c)/2;w1=(a+b)/2;
p[x_]:={-x[[2]],x[[1]]};u2=u1+p[c-b];v2=v1+p[c-a];w2=w1+p[a-b];
L[x_,y_,z_,w_]:=x+(t/.Solve[x+t (y-x)==z+s (w-z),{t,s}][[1]])(y-x);
Simplify[L[u1,u2,v1,v2]==L[u1,u2,w1,w2]==L[v1,v2,w1,w2]]

Inscribed Circle Center

a={a1,a2};b={b1,b2};c={c1,c2};
f[a_,b_,c_]:=a+((b-a)/Sqrt[(b-a).(b-a)]+(c-a)/Sqrt[(c-a).(c-a)])/2
u=f[a,b,c];v=f[b,c,a];w=f[c,a,b];
L[x_,y_,z_,w_]:=x+(t/.Solve[x+t (y-x)==z+s (w-z),{t,s}][[1]])(y-x);
Simplify[L[a,u,b,v]==L[a,u,c,w]==L[b,v,c,w]]