Quadratic Map Connectivity Problems

The first and last problem might be easier than the second one. The problem is to find the probability of having connectivity using quadratic maps.

Oliver Knill,   November  22, 2013

QuadraticGraph[n_,c_]:=Module[{T},T[x_]:=Mod[x^2+c,n];UndirectedGraph[Graph[Table[x->T[x],{x,0,n-1}]]]];
QuadraticGraph[n_,c_,d_]:=Module[{T,S},T[x_]:=Mod[x^2+c,n];S[x_]:=Mod[x^2+d,n];
UndirectedGraph[Graph[Union[Table[x->T[x],{x,0,n-1}],Table[x->S[x],{x,0,n-1}]]]]];
QuadraticGraph[n_,c_,d_,e_]:=Module[{T,S,U},T[x_]:=Mod[x^2+c,n];S[x_]:=Mod[x^2+d,n];U[x_]:=Mod[x^2+e,n];
UndirectedGraph[Graph[Union[Table[x->T[x],{x,0,n-1}],Table[x->S[x],{x,0,n-1}],Table[x->U[x],{x,0,n-1}]]]]];

M=10;GraphicsGrid[{{GraphPlot[QuadraticGraph[M,1]],GraphPlot[QuadraticGraph[M,1,2]],GraphPlot[QuadraticGraph[M,1,2,3]]}}]

Quadratic Graph Problem I

G1[M_]:=Module[{F,U,V},F[a_]:=Length[ConnectedComponents[QuadraticGraph[M,a]]];
U=Flatten[Table[F[a],{a,0,M-1}]];V={Length[U],Length[Position[U,1]]};V[[2]]/V[[1]]];
H1[k_]:=N[(1/Prime[k]) G1[Prime[k]]*k^2/Log[k]];
ListPlot[Table[H1[k],{k,10,100}],Joined->True,PlotRange->{0,1}]

H1[100]

Quadratic Graph Problem II

G2[M_]:=Module[{F,U,V},F[a_,b_]:=Length[ConnectedComponents[QuadraticGraph[M,a,b]]];
U=Flatten[Table[F[a,b],{a,0,M-1},{b,a+1,M-1}]];
V={Length[U],Length[Position[U,1]]};V[[2]]/V[[1]]];
H2[k_]:=(1-G2[Prime[k]])*(k/Log[Prime[k]])^2;
ListPlot[Table[N[H2[k]],{k,3,50}],Joined->True]

H2[50] //N

Quadratic Graph Problem III

G3[M_]:=Module[{F,U,V},F[a_,b_,c_]:=Length[ConnectedComponents[QuadraticGraph[M,a,b,c]]];
U=Flatten[Table[F[a,b,c],{a,0,M-1},{b,a+1,M-1},{c,b+1,M-1}]];
V={Length[U],Length[Position[U,1]]};V[[2]]/V[[1]]];
H3[k_]:=G3[Prime[k]];
Table[H3[k],{k,3,20}]

H3[20]