Pecha - Kucha

Oliver Knill, March 6, 2013, Updated October 9, 2025 for Mathematica 14.2

Here is some Mathematica code illustrating some of the slides of the talk.

The deformed Polynomials

Pow[x_,h_,n_]:=Product[(x-h j),{j,0,n-1}];
Manipulate[GraphicsGrid[Partition[Table[Plot[Pow[x,h,k],{x,0,3},Ticks->None,AspectRatio->1],{k,0,5}],3]],{h,1,0.01}]

The deformed Exponential

Manipulate[Plot[(1+h)^(x/h),{x,0,3},PlotRange->{0,10}],{h,1,0.01}]

The deformed Trig functions

HExp[x_,a_,h_]:=(1+a h)^(x/h);
Manipulate[Plot[{Sin[x],Im[HExp[x,I,h]]},{x,0,5},PlotStyle->{Yellow,Red}],{h,1,0.01}]

Harmonic Oscillator

Manipulate[ParametricPlot[ {Re[HExp[x,I,h]],Im[HExp[x,I,h]]},{x,0,10Pi}],{h,0.1,0.001}]

Taylor Theorem

f0[x_]:=Cos[x/2];M=13;
Di[f_]:=Function[m,f[m+1]-f[m]];
diff[f_,k_]:=Module[{g,h},h=f;Do[g=Di[h];h=g,{j,k}];h];
Pow[x_,n_]:=Product[(x-j),{j,0,n-1}];
TaylorCoefficients[f_]:=Table[g=diff[f,k];g[0],{k,0,M}]
a=TaylorCoefficients[f0];
f1[x_]:=Sum[Pow[x,j] a[[j+1]]/j!,{j,0,Length[a]-1}];
S1=Plot[{f0[x],f1[x]},{x,0,M},PlotStyle->{{Thickness[0.01],Blue},{Thickness[0.01],Green}},AspectRatio->1,PlotRange->All];
S2=Graphics[Table[{Red,PointSize[0.05],Point[{k,f1[k]}]},{k,0,M-1}]];
Show[{S1,S2}]

Dow Jones Data fitting

c=FinancialData["DJI",{{2000,1,1},{2020,1,1}}];
A=c[[2,1,1]];

data=Table[A[[k]],{k,Length[A]-20,Length[A]}];
M=Length[data];m[x_]:=Max[Min[M,Round[x]],1];
f0[x_]:=data[[m[x]]];
Di[f_]:=Function[m,f[m+1]-f[m]];
diff[f_,k_]:=Module[{g,h},h=f;Do[g=Di[h];h=g,{j,k}];h];
Pow[x_,n_]:=Product[(x-j),{j,0,n-1}];
TaylorCoefficients[f_]:=Table[g=diff[f,k];g[0],{k,0,M}]
a=TaylorCoefficients[f0];
ff[x_]:=Sum[Pow[x,j] a[[j+1]]/j!,{j,0,Length[a]-1}];
Plot[{ff[x],f0[x]},{x,1,M},PlotStyle->{{Thickness[0.005],Red},{Thickness[0.005],Blue}},AspectRatio->1]